Skip to main content

Current draw of ATtiny85 ticking clock using watchdog timer

I modified the previous watchdog timer code to test the current draw of ATtiny85 ticking a clock using POWER_DOWN deep sleep.

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
#include <avr/io.h>
#include <avr/wdt.h>
#include <avr/sleep.h>
#include <avr/interrupt.h>
#include <avr/power.h>

#define TIMER0_PRESCALER 1024
#define OCR0A_DEFVAL ((byte)(F_CPU / (float)TIMER0_PRESCALER * 200/1000.0) - 1)
#define adc_disable() (ADCSRA &= ~(1<<ADEN)) // disable ADC (before power-off)

volatile byte timer0_tickpin = PB3;
volatile bool wdtimer = false;

void startTimer0() {
  // Set prescaler to 1024, thereby starting Timer0
  TCCR0B = bit(CS02) | bit(CS00); 
}

void stopTimer0() {
  // Set prescaler to 0, thereby stopping Timer0
  TCCR0B = 0;
}

// Interrupt service routine for Timer0
// The effective outcome is to toggle tickpin high for 100ms, then rest for 200ms
ISR(TIMER0_COMPA_vect) {
    stopTimer0();
    digitalWrite(timer0_tickpin, LOW);
    timer0_tickpin = (timer0_tickpin == PB3 ? PB4: PB3);
}

ISR(WDT_vect) {
  wdtimer = true;
}

void setup() {
  pinMode(PB3, OUTPUT); digitalWrite(PB3, LOW);
  pinMode(PB4, OUTPUT); digitalWrite(PB4, LOW);

  power_adc_disable();

  // Reset prescalers for Timer0 and Timer1
  GTCCR |= bit(PSR0) | bit(PSR1);

  // Setup Timer0 (but don't run it yet)
  TCCR0A = 0;
  TCCR0B = 0;
  TCNT0  = 0;
  TCCR0A = bit(WGM01); // CTC mode
  OCR0A = OCR0A_DEFVAL;

  // Interrupt on compare match with OCR0A
  TIMSK |= bit(OCIE0A);

  // Set up watchdog timer
  MCUSR &= ~_BV(WDRF);
  WDTCR |= (_BV(WDCE) | _BV(WDE));   // Enable the WD Change Bit
  WDTCR =   _BV(WDIE) |              // Enable WDT Interrupt
    _BV(WDP2) | _BV(WDP1);           // Set Timeout to ~1 seconds (or something)

  set_sleep_mode(SLEEP_MODE_PWR_DOWN);
  sleep_mode();
}

void loop() {
  if (wdtimer) {
    wdtimer = false;
    digitalWrite(timer0_tickpin, HIGH);
    startTimer0();
    set_sleep_mode(SLEEP_MODE_IDLE);
    sleep_mode();
  } else {
    set_sleep_mode(SLEEP_MODE_PWR_DOWN);
    sleep_mode();
  }
}

In summary, the watchdog timer wakes up the ATtiny85 every sec. The tickpin is toggled within a 200ms window using IDLE sleep (via Timer0), then it will go back to deep sleep for 800ms. The current draw as measured is 1.7mA.

If the deep sleep current draw of the D1 Mini can be reduced from 0.8 to 0.1mA by using a barebones ESP8266, then the current draw of the ATtiny85 is only 1mA.

Labels:

Comments

Post a Comment

Popular posts from this blog

Hacking an analog clock to sync with NTP - Part 5

This is how it looks after I have put everything together. The Arduino sketch is available here . The 2 jumper wires soldered to the clock mechanism are connected to pins D0 and D1 on the ESP-12 (in any order). When the device first boots up, it presents an access point which can be connected to via the PC or smartphone. Once connected, the captive portal redirects the web browser to the configuration page:     A custom field has been added to the WiFi configuration page to enter the current clock time in HHMMSS format. Try to set the clock time to as close to the current time as possible using the radial dial at the back of the clock so the clock will have less work to do catching up. In the config page, the HTML5 Geolocation API is also used to obtain your current location (so if your web browser asks if you would like to share your location, answer "yes"). This is then passed to the Google Time Zone API to obtain the time and DST offset of your time z...
23 comments
Read more

Cooling mod for the X96 Air

I realized after my Ugoos box died that overheating is a big problem with cheap Android TV boxes. A teardown of the Ugoos box shows that it does not have any heatsink or fan at all!  The X96 Air does have a heatsink, but the heatsink is located at the bottom of the casing with no ventilation. In this default configuration, with the ambient room temperature at 25c and playing a 1080p video, I was seeing the CPU temperature at 67c. I drilled a couple of holes at the bottom of the casing. The CPU temperature fell to 59c with the box raised about 2cm with plastic blocks. I retrieved an old 5V laptop fan: Then cut and strip away a spare USB cable: Solder the red and black wires on the fan and the cable: Secure the fan to the bottom of the casing with double-sided tape, then plug the fan into the box's USB connector. Here's a view of the box with some 3D-printed risers installed at the bottom to give the mounted fan sufficient clearance: The CPU now runs at 43c, a huge drop from the ...
2 comments
Read more

Cooling mod for the X96 Air #2

Previously, I added a USB cooling fan to the X96 Air TV box . The problem with this mod is that the fan is always running, and it runs at full speed. Ideally, the fan should kick in only when the CPU temperature is above a certain threshold. It would be even better if there is a way to control the fan speed. Dan McDonald left me a comment pointing to his project on Github . He basically connected the fan to a USB relay that can be controlled by Python script. His project inspired me to make a similar mod that would make use of the spare D1 Mini boards I have lying around. The plan is to hook up the fan to a MOSFET (2N7000) and control it via PWM. Here's the very simple circuit: The code simply reads a single character from the serial port (0 - 9). 0 will turn the fan off, while 1 - 9 will generate a proportional PWM to drive the fan, with 1 being the lowest and 9 being the highest. Here's the Arduino code: #include <Arduino.h> void setup () { Serial . begin ( 9600 ...
1 comment
Read more