Skip to main content

Attiny85 timer programming using Timer1

This Arduino sketch uses Timer1 to drive the LED blinker:

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
/*
 * Program ATTiny85 to blink LED connected to PB1 at 1s interval.
 * Assumes ATTiny85 is running at 1MHz internal clock speed.
 */

#include <avr/io.h>
#include <avr/wdt.h>
#include <avr/sleep.h>
#include <avr/interrupt.h>

bool timer1 = false, led = true;

// Interrupt service routine for timer1
ISR(TIMER1_COMPA_vect)
{
  timer1 = true;
}

void setup() {

  // Setup output pins
  pinMode(1, OUTPUT);
  digitalWrite(1, led);
  set_sleep_mode(SLEEP_MODE_IDLE);

  // Setup timer1 to interrupt every second
  TCCR1 = 0; // Stop timer
  TCNT1 = 0; // Zero timer
  GTCCR = _BV(PSR1); // Reset prescaler
  OCR1A = 243; // T = prescaler / 1MHz = 0.004096s; OCR1A = (1s/T) - 1 = 243
  OCR1C = 243; // Set to same value to reset timer1 to 0 after a compare match
  TIMSK = _BV(OCIE1A); // Interrupt on compare match with OCR1A
  
  // Start timer in CTC mode; prescaler = 4096; 
  TCCR1 = _BV(CTC1) | _BV(CS13) | _BV(CS12) | _BV(CS10);
  sei();
}

void loop() {
  if (timer1) {
    timer1 = false;
    led = !led;
    digitalWrite(1, led);
  }
  sleep_enable();
  sleep_cpu(); // CPU goes to sleep here; will be woken up by timer1 interrupt
}

The internal RC oscillator can have a factory variance of up to 10%. I observe that my blinker pulsed slightly faster than 1Hz.

Thankfully, unlike the watchdog oscillator, the internal RC oscillator can be calibrated by using the OSCCAL register, or adjusting the value of OCR1A. I believe it should not be too difficult to automatically calibrate the oscillator between NTP calls by taking the difference in actual time and clock time (in seconds) and adjust OCR1A accordingly to get as close to 1Hz as possible.

So on initial startup, the ESPCLOCK may not be pulsing at 1Hz, but after 15 or 30 minutes, it should be fully calibrated.

The downside with this approach is we can only use SLEEP_MODE_IDLE to keep Timer1 running during sleep, which is not as power efficient  as using the Watchdog Timer.
Labels:

Comments

  1. Unknown20 October 2017 at 03:41

    Hi .help me to change the function from arduino codes at attyni85 usb .please help with .thanks
    void setup() {
    // put your setup code here, to run once:

    //timer2
    OCR2A = 127; //50% duty cycle
    TCCR2A = _BV(COM2A0) | _BV(WGM21) | _BV(WGM20); //toggle output, fast PWM mode
    TCCR2B = _BV(WGM22) | _BV(CS21) | _BV(CS20); // fast PWM mode, prescale 1:64
    pinMode(11, OUTPUT);

    }

    void loop()
    {

    delay(200); //duration of each frequency
    OCR2A += 10; //step size of frequency change
    if(OCR2A >= 245){OCR2A = 10; } //range of sweep, 245 is max.

    }

    ReplyDelete
  2. ian1235 July 2021 at 15:02

    there are only 2 timers on attiny85, timer0 and timer1

    ReplyDelete

Post a Comment

Popular posts from this blog

Cooling mod for the X96 Air #2

Previously, I added a USB cooling fan to the X96 Air TV box . The problem with this mod is that the fan is always running, and it runs at full speed. Ideally, the fan should kick in only when the CPU temperature is above a certain threshold. It would be even better if there is a way to control the fan speed. Dan McDonald left me a comment pointing to his project on Github . He basically connected the fan to a USB relay that can be controlled by Python script. His project inspired me to make a similar mod that would make use of the spare D1 Mini boards I have lying around. The plan is to hook up the fan to a MOSFET (2N7000) and control it via PWM. Here's the very simple circuit: The code simply reads a single character from the serial port (0 - 9). 0 will turn the fan off, while 1 - 9 will generate a proportional PWM to drive the fan, with 1 being the lowest and 9 being the highest. Here's the Arduino code: #include <Arduino.h> void setup () { Serial . begin ( 9600 ...
1 comment
Read more

Installing and customizing CoreELEC in X96 Air

I previously installed CoreELEC on another TV Box ( Ugoos X3 Pro ), which unfortunately died after only 9 months during the summer (due to the unit overheating, which I learned is a common problem for cheap Android TV boxes). So this time I purchased a X96 Air  (4GB/32Gb) and had to do the whole thing again. So this is a note-to-self in case I ever have to install CoreELEC again on some other device. Installation of CoreELEC is simple enough by following this guide . Basically, it involves downloading and writing the firmware to a microSD card using usbimager . Then insert the microSD card, reset the unit and hold the reset until the logo appears. The unit will then proceed to boot into CoreELEC. First thing is to connect to WiFi, then enable SSH. This allows me to login via ssh and execute: ceemmc -x from the terminal. This writes CoreELEC to the built-in eMMC storage, after which I am able to remove the microSD card and reboot the unit into CoreELEC via the built-in sto...
Post a Comment
Read more

DC-DC Buck Stepdown Converter for ESP8266

I am working on a project that requires a step-down converter from 12V to 5V, that will then power a WeMOS D1 Mini. I saw this new mini buck converter based on the usual LM2596 MP2307 , so I thought I'd give it a try. Unfortunately, it didn't work. Although it is supposed to be able to supply up to 1.8A, the D1 Mini was not able to boot up. The 5V pin was being properly supplied, but the 3.3V pin measures at only ~1.3V. So I had to go back to my usual LM2596 module, which is much larger, but works to power the D1 Mini with a 12V source. Here's a great review of the mini buck converter I found while trying to figure out how to make it work. The fact that it has high quiescent current (~60mA) is also mentioned in a few other sources.
Post a Comment
Read more